object-e architecture/tools

1D Cellular Automata v1.0.ms

2009-07-13T10:01:00.000-07:00

A MaxScript one dimentional cellular automaton algorithm. Similar to the .mel script, but much more elaborate. It implements rules 30, 54, 60, 62, 90, 94, 102, 110, 122, 126, 150, 158, 182, 188, 190, 220, 222 and 250. To use run the script and go under utilities/maxscript.

You can download the script here.

2.5D Cellular Automaton v.1.0

2009-05-12T11:00:00.000-07:00

A 2-dimentional cellular automaton algorithm that simulates the ca and represents the different generations as different 'layers' of cubes in maya.

download the file here.

2D Cellular Automaton v.1.0

2009-05-12T10:55:00.000-07:00

A 2-dimentional cellular automaton algorithm that animate the growh of the ca in maya using MEL.

download the file here

1D Cellular Automaton v1.0

2009-05-12T02:36:00.000-07:00

This is a basic 1D Cellular automaton mel scripts tha simulates the automaton and represents its growth in maya with planes as cells.

Download the file here

Attractor_panels

2009-03-30T08:33:00.000-07:00

A definition that creates rectangular panels with circular holes. The size of the hole is defined in relation to the distance of each panel to a user defined point. There is also a 'range' function that specifies a radius around the point where it is 'active'. The definition here

triangulate surface definition

2008-06-19T22:56:00.001-07:00

A definition for grasshopper that will triangulate any custom surface

download the definition here

rectangular panels definition

2008-06-19T22:38:00.000-07:00

A definition for grasshopper, that creates rectangular panels on a custom surface. Note that the panels are not flat.

download the definition here

brownian motion

2008-06-19T14:44:00.000-07:00

A small script to simulate brownian motion in 3dstudio max. The script has to be placed in a script operator for the particles.


--
-----------------------------------------------------------------------------------
--\\\\\\\\_________________________BROWNIAN MOTION_________________________////////
--////////                                                                 \\\\\\\\
-----------------------------------------------------------------------------------
--> Written by dimitris gourdoukis.
--> object-e architecture 2007.
-----------------------------------------------------------------------------------
--> http://object-e.blogspot.com/
--> object.e.architecture@gmail.com
-----------------------------------------------------------------------------------
--> Last Modified 9/14/07.
--> Use and modify at your own risk.
-----------------------------------------------------------------------------------
--> Description:
--  This is a simple script to simulate brownian motion with particles. Paste  
--  the script in a script operator in the particle view.
-----------------------------------------------------------------------------------


on ChannelsUsed pCont do (
 pCont.useSpeed = true  --enable the Float channel
)

on Init pCont do (
  )

on Proceed pCont do(

 --Get the number of particles
 count = pCont.NumParticles()
 --create a for loop for the number of particles
 for i in 1 to count do (

  --set the particle index to i
  pCont.particleIndex = i
  --give a random speed to the particles
  pCont.particleSpeed = (random [-0.2,-0.2,-0.2] [0.2,0.2,0.2])

 )
)
on Release pCont do (
 )

Animate Sequence v.1.0

2008-06-19T14:39:00.000-07:00


/*
-------------------------------------------------------------------------------------
\\\\\\\\________________________ANIMATE SEQUENCE v1.0________________________////////
////////                                                                     \\\\\\\\
-------------------------------------------------------------------------------------
> Written by dimitris gourdoukis.
> object-e architecture 2008.
-------------------------------------------------------------------------------------
> http://object-e.blogspot.com/
> object.e.architecture@gmail.com
-------------------------------------------------------------------------------------
> v1.0 Last Modified 4/26/08.
> Use and modify at your own risk.
-------------------------------------------------------------------------------------
> Description:
 This script animates sequentially the creation of the selected objects by setting 
 their scale value to 0 and then back to 1. The order of the selection defines the 
 order of the animation. Start frame value specifies the frame where the animation 
 begins. Duration value specifies the number of frames after which each new object 
 is created.
-------------------------------------------------------------------------------------
*/

proc animateSequence (){

 //list the selected objects
 string $list[] = `ls -sl`;
 //get the size of the array
 $size = size($list);

 int $startFrame = `intSliderGrp -q -v startFrame`;
 int $duration = `intSliderGrp -q -v duration`;

 //start a loop for each object in the array
 for ($i=0; $i<$size; $i++){
  string $selObject = $list[$i];
  //$dur = 5;
  select -r $selObject;
  currentTime ($startFrame + $i*$duration);

  
  string $parsex = $selObject + ".scaleX";
  string $parsey = $selObject + ".scaleY";
  string $parsez = $selObject + ".scaleZ";

  setAttr $parsex 0;
  setAttr $parsey 0;
  setAttr $parsez 0;
  setKeyframe $selObject.sx;
  setKeyframe $selObject.sy;
  setKeyframe $selObject.sz;

  currentTime ($startFrame + ($i*$duration) + $duration) ;

  
  setAttr $parsex 1;
  setAttr $parsey 1;
  setAttr $parsez 1;
  setKeyframe $selObject.sx;
  setKeyframe $selObject.sy;
  setKeyframe $selObject.sz;

 }
}

global proc constructAnimWin ()
{
 if (`window -exists animateWindow`) { 
  deleteUI animateWindow; 
 }


 window
 -width 400
 -height 200
 -title "animate sequence"
 -sizeable true
 animateWindow;

 columnLayout;

 text -l "";

 intSliderGrp -label "start frame"
 -field true
 -fieldStep 1
 -sliderStep 1
 -value 0
 -fieldMinValue -100 -fieldMaxValue 1000
 startFrame;

 intSliderGrp -label "duration"
 -field true
 -value 5
 duration;

 //create button
 button -label "Animate"
 -command "animateSequence" buildIt;

 setParent ..;

 //break
 columnLayout;
 text -l "";
 separator -w 800 -h 4 -backgroundColor 1 0.663 1;
 text -l "object-e / dimitris gourdoukis. 2008.";
 text -l "http://object-e.blogspot.com/";
  
 showWindow;
}

constructAnimWin;

pipe curves v1.0

2008-06-05T16:55:00.000-07:00

A simple script intended to help with the creation of multiple pipe objects out of a collection of curves in Maya.



/*
-------------------------------------------------------------------------------------
\\\\\\\\__________________________PIPE CURVES v1.0___________________________////////
////////                                                                     \\\\\\\\
-------------------------------------------------------------------------------------
> Written by dimitris gourdoukis.
> object-e architecture 2008.
-------------------------------------------------------------------------------------
> http://object-e.blogspot.com/
> object.e.architecture@gmail.com
-------------------------------------------------------------------------------------
> v1.0 Last Modified 5/18/08.
> Use and modify at your own risk.
-------------------------------------------------------------------------------------
> Description:
 This script creates pipes around each of the selected curves and 'caps' the pipes
 by placing one sphere on both ends of the curve.
-------------------------------------------------------------------------------------
*/


proc pipeCurves (){

 //list the selected curves
 string $curvelist[] = `ls -sl`;;
 $size = size($curvelist);

 float $pipeRadius = `floatSliderGrp -q -v pipeRadius`;

 //create the profile circle
 circle -ch on -o on -nr 0 1 0 -r $pipeRadius -n profile;

 for ($i=0; $i<$size; $i++){

  //extrude the profile along the curve
  extrude -ch true -rn false -po 0 -et 2 -ucp 1 -fpt 1 -upn 1 -rotation 0 -scale 1 -rsp 1 "profile" $curvelist[$i] ;

  //get the number of cvs
  string $xero1 = "getAttr \"" + $curvelist[$i] + ".cv[*]\"";
  float $convs [] = eval ($xero1);
  $arraySize = size($convs);
  int $lastCV = $arraySize/3 - 1;

  //get the coordinates of the start point
  string $xero2 = "getAttr \"" + $curvelist[$i] + ".cv[0]\"";
  vector $start = eval ($xero2);
  $ssx = $start.x;
  $ssy = $start.y;
  $ssz = $start.z;

  //get the coordinates of the end point
  string $xero3 = "getAttr \"" + $curvelist[$i] + ".cv[" + $lastCV + "]\"";
  vector $end = eval ($xero3);
  $sex = $end.x;
  $sey = $end.y;
  $sez = $end.z;

  //create and move the spheres
  polySphere -r $pipeRadius;
  move $ssx $ssy $ssz;

  polySphere -r $pipeRadius;
  move $sex $sey $sez;
 }

 select -r profile ;
 doDelete;
}


global proc constructPipeWin ()
{
 if (`window -exists pipeWindow`) {
  deleteUI pipeWindow;
 }


 window
 -width 400
 -height 200
 -title "pipe curves"
 -sizeable true
 pipeWindow;

 columnLayout;

 text -l "";

 floatSliderGrp -label "radius"
 -field true
 -fieldStep 0.1
 -sliderStep 0.1
 -value 1
 -fieldMinValue 0 -fieldMaxValue 100
 pipeRadius;


 //create button
 button -label "Pipe"
 -command "pipeCurves" buildIt;

 setParent ..;

 //break
 columnLayout;
 text -l "";
 separator -w 800 -h 4 -backgroundColor 1 0.663 1;
 text -l "object-e / dimitris gourdoukis. 2008.";
 text -l "http://object-e.blogspot.com/";

 showWindow;
}

constructPipeWin;